desenv-web-rp.com

Existe alguma ferramenta de linha de comando que possa ser usada para editar variáveis ​​de ambiente no Windows?

Existe alguma ferramenta de linha de comando que possa ser usada para editar variáveis ​​de ambiente no Windows?

Seria bom se isso fosse uma ferramenta inteligente, por exemplo:

  • Ao adicionar algum caminho a dizer a variável de caminho e esse caminho já não deve dobrar esta entrada.
  • Inserir um novo caminho para a variável de caminho deve ser possível antes/depois de algum outro caminho ou em ordem específica (o primeiro, o 7º, o último etc.).
  • Deve ser possível alterar apenas parte do valor da variável (no caso do caminho um determinado caminho de uma lista de todos os caminhos).

E o último, mas não menos importante - Eu quero que minhas alterações persistem entre as sessões O conjunto tão simples está fora de questão ...

Há uma ferramenta GUI muito boa para este chamado editor de caminho e eu preciso de algo assim, mas para a linha de comando.

15
Piotr Dobrogost

Não conheço nenhuma ferramenta que faça isso, mas talvez você possa usar o regcommand:

reg query "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v Path

para ler o caminho atual e

reg add "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v Path /d "newPath" /f

para escrever seu novo valor.

Você precisa de direitos de administrador para o Acccess direito de HSving em HKLM. Se isso é um problema, considere modificar a configuração do caminho específico do usuário em HKCU\Environment em vez de.

16
Treb

Se você precisar de uma maneira genérica de definir qualquer variável de ambiente e ter as alterações persistirem, então setx.exe seria a ferramenta para usar. Não pode fazer as coisas "inteligentes" que você está pedindo, embora ...

sETX.EXE está incluído no Windows Vista ou posterior; Se você usar uma versão anterior do Windows, poderá usar o link de download acima para obtê-lo.

7
bobbymcr

Para o programa atual, há path:

Exibe ou define um caminho de pesquisa para arquivos executáveis.

PATH [[drive:]path[;...][;%PATH%]
PATH ;

Modelo PATH ; Para limpar todas as configurações de caminho de pesquisa e direto cmd.exe Para pesquisar apenas no diretório atual.

Digite PATH sem parâmetros para exibir o caminho atual. Incluindo %PATH% Na nova configuração do caminho faz com que o caminho antigo seja anexado à nova configuração.

No entanto, isso é praticamente o mesmo que set PATH.

Para as variáveis ​​de ambiente para persistir, você deve editar o registro ou usar setx.

5
Joey

Acabei de descobrir a capacidade de permitir que os usuários executassem a caixa de diálogo Editar variáveis ​​de ambiente sem privilégios elevados.

No menu Iniciar, execute o seguinte:

rundll32 sysdm.cpl,EditEnvironmentVariables
3
David Tersigni

Você pode querer verificar a coleção GTools : http://www.p-nand-q.com/gtools.html

Ele fornece um conjunto de comandos para o comando promt como

pathed /APPEND %CD% /USER

para anexar o caminho atual, por exemplo. Eu realmente não verifiquei para ser honesto, como estou totalmente bem com o uso de uma GUI.

Outras opções são:

  /MACHINE: print machine PATH
     /USER: print user PATH
      /ADD: add variable at the head
   /APPEND: add variable at the tail
   /REMOVE: remove path / index
     /SLIM: strip duplicate vars
      /ENV: environment variable, defaults to PATH

Juntamente com qual da mesma coleção, você tem algumas boas ferramentas, suponho. Que "localiza arquivos executáveis ​​no caminho".

 /EXTENSION: search for extension , can be a ; separated list
       /DIR: add directory , can be a ; separated list
 /RECURSIVE: search directories recursively
    /SINGLE: stop after the first find result
       /ENV: environment variable, defaults to PATH
FILE {FILE}: one or more files to find

Fonte: http://op111.net/82/

2
hugo der hungrige

definir caminho

(Ajuda definida)

2
sangretu

Eu escrevi um conjunto de scripts em lote para isso. AddPath.bat adiciona elementos ao caminho, RMPath.bat remove elementos do caminho e lpath.bat apenas lista o caminho. Mas então eu precisava de alguns scripts de suporte, então também há chkpath.bat.

Acabou sendo não trivial e exigido tr.exe e cat.exe, um par de utilitários de estilo UNIX. A razão não é trivial: sem backticks em cmd.exe (embora você possa usar por loops para isso) e nomes curtos versus nomes longos.

addPath.bat:

@echo off
setlocal
set cwd=%~dps0

goto testit

:loopy

call %cwd%chkpath "%~1"
if %errorlevel%==2 (
  set path=%path%;%~1
)

shift

:testit
if not _%1==_ goto loopy


call %cwd%lpath.bat

endlocal & set path=%path%

Chkpath.bat:

@echo off
goto START

-------------------------------------------------------
chkpath.bat

checks path for existence of the given segment.
Returns 1 if present, 2 if not present, 0 if not checked.

The matching and checking complicated by case sensitivity and "short pathnames".

created sometime in 2003 and lovingly maintained since then.


-------------------------------------------------------

:START
setlocal enabledelayedExpansion
set rc=0
set cwd=%~dps0
set curdrive=%~d0
set tr=%curdrive%\bin\tr.exe
set regexe=%windir%\system32\reg.exe


if _%1==_ goto Usage


@REM convert arg 1 to a fully-qualified, short path name,
@REM and then convert to uppercase.
set toupper=%~fs1
call :ToUpper
set tocheck=%toupper%


if not _%TEMP%==_ goto GotTemp
call :gettemp


:GotTemp
set d=%DATE:~4%
set stamp=%d:~6%%d:~3,2%%d:~0,2%%TIME::=%
set d=
set tempfile1=%TEMP%\chkpath1-%stamp%.tmp

echo %path% | %tr% ; \n  >  %tempfile1%

@REM check each element in the path for the match:
for /f  "delims=^" %%I in (%tempfile1%) do (
  if !rc!==0 (
call :CheckElt "%%I"
  )
)

if %rc%==0 set rc=2
goto END


--------------------------------------------
* checkelt
*
* check one element in the path to see if it is the same
* as the TOCHECK string. The element is first canonicalized.
*

:CheckElt
@REM remove surrounding quotes
set ERF=%1
if [x%ERF%]==[x] goto CheckEltDone
@REM convert to fully-qualified, short paths, uppercase
set TOUPPER=%~fs1%
call :ToUpper
if _%TOCHECK% == _%TOUPPER% set rc=1
:CheckEltDone
goto:EOF
--------------------------------------------


--------------------------------------------
* backtick
*
* invoke a command and return the result as a string.
* This is like backtick in csh or bash.
* To call, set variable BACKTICK to the command to be run.
* The result will be stored in the env variable of the same name.
*

:backtick
FOR /F "usebackq delims=" %%i IN (`%backtick%`) DO (
  SET backtick=%%i
)
goto backtick_done
:backtick_none
  SET backtick=nothing to exec
:backtick_done
goto:EOF
--------------------------------------------


--------------------------------------------
* gettemp
*
* get the temporary directory, as stored in the registry.
* Relies on backtick.
*
* The result set TEMP.
*

:gettemp
set regkey=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders
set regvalname=Local AppData
set backtick=%regexe% query "%regkey%" /v "%regvalname%"
call :backtick
for /f "tokens=4" %%a in ("%backtick%") do (
  set temp=%%a
)
goto:EOF
--------------------------------------------



--------------------------------------------
* ToUpper
*
* Convert a string to all uppercase.
* To call, set variable TOUPPER to the thing to be converted.
* The result will be stored in the env variable of the same name.
*

:ToUpper
  FOR /F "usebackq delims=" %%I IN (`echo %toupper% ^| %tr% a-z A-Z`) DO (
SET toupper=%%I
  )
goto:EOF
--------------------------------------------


--------------------------------------------
:CleanUp
  if _%tempfile1%==_ goto CleanUpDone
  if exist %tempfile1% del %tempfile1%
  :CleanUpDone
goto:EOF
--------------------------------------------


--------------------------------------------
:Usage
echo.
echo Usage: chkpath ^<path^>
echo checks if path element is included in path variable.
echo returns 1 if yes, 2 if no, 0 if not checked.
echo.
goto END
--------------------------------------------


:END
call :CleanUp

:ReallyEnd

endlocal & set errorlevel=%rc%
@REM set errorlevel=%rc%
@REM echo %errorlevel%

lpath.bat:

@echo.
@set curdrive=%~d0

@REM This form post-fixes a | at the end of each path element. Useful for debugging trailing spaces.
@REM @path | %curdrive%\cygwin\bin\sed.exe -e s/PATH=// -e 's/;/^|\n/g' -e 's/$/^|/g'

@REM This form shows bare path elements.
@REM @path | %curdrive%\cygwin\bin\sed.exe -e 's/PATH=//' -e 's/;/^\n/g'
@path | %curdrive%\utils\sed -e "s/PATH=//" | %curdrive%\utils\tr ; \n
@echo.
1
Cheeso

Como verificar se o diretório existe em% Path%? On Stack Overflow tem um descrição excepcional do que torna o Windows Path Editing difícil junto com um arquivo em lote para superá-los. Descobrir como usar adequadamente addpath.bat Tomei um pouco de prática como sua estrutura de chamadas era nova para mim, mas isso funciona:

set _path=C:\new\directory\to\add\to\path
call addpath.bat _path
set _path=

e as disparadas repetidas não adicionam o novo diretório se já estiver presente. Isso não aborda as edições persistentes entre as sessões.

0
matt wilkie